{ pkgs, lib, config, modulesPath, ... }:

{
  imports = [
    (modulesPath + "/installer/cd-dvd/installation-cd-base.nix")
  ];

  disabledModules = [
    "profiles/base.nix"
  ];

  nixpkgs.overlays = [ (import ./packages) ];

  networking.hostName = "netalis-nixos-iso";
  isoImage.isoBaseName = "netalis-nixos-iso";

  boot.supportedFilesystems =
    [ "btrfs" "cifs" "f2fs" "jfs" "ntfs" "reiserfs" "vfat" "xfs" ] ++
    lib.optional (lib.meta.availableOn pkgs.stdenv.hostPlatform config.boot.zfs.package) "zfs";

  # Configure host id for ZFS to work
  networking.hostId = lib.mkDefault "8425e349";

  nix = {
    settings = {
      trusted-users = [ "@wheel" ];
      experimental-features = [ "nix-command" "flakes" "repl-flake" ];
      auto-optimise-store = true;
    };
    extraOptions = ''
      min-free = ${toString (100 * 1024 * 1024)}
      max-free = ${toString (1024 * 1024 * 1024)}
    '';
    nixPath = lib.mkForce [ "nixpkgs=${lib.cleanSource pkgs.path}" ];
    registry = lib.mkForce {
      "nixpkgs" = {
        from = {
          type = "indirect";
          id = "nixpkgs";
        };
        to = {
          type = "path";
          path = lib.cleanSource pkgs.path;
        };
        exact = true;
      };
    };
  };

  environment.systemPackages = with pkgs; [
    w3m-nographics # needed for the manual anyway
    testdisk # useful for repairing boot problems
    ms-sys # for writing Microsoft boot sectors / MBRs
    efibootmgr
    efivar
    htop
    parted
    gptfdisk
    ddrescue
    ccrypt
    cryptsetup # needed for dm-crypt volumes

    # Some text editors.
    (vim.customize {
      name = "vim";
      vimrcConfig.customRC = ''
        filetype plugin indent on
        set tabstop=4
        set shiftwidth=4
        set expandtab
        set modeline
        set modelines=1
        set encoding=utf-8
        syntax on
        au BufRead,BufNewFile *.nix set ts=2 sw=2
      '';
    })

    # Some networking tools.
    fuse
    fuse3
    sshfs-fuse
    socat
    screen
    tcpdump

    # Hardware-related tools.
    sdparm
    hdparm
    smartmontools # for diagnosing hard disks
    pciutils
    usbutils
    nvme-cli

    # Some compression/archiver tools.
    unzip
    zip

    # own packages
    netali-configure-net-ruby
    netali-default-config-ruby
  ];

  time.timeZone = "Europe/Berlin";

  i18n.defaultLocale = "en_US.UTF-8";
  console = {
    font = "Lat2-Terminus16";
    keyMap = "de-latin1";
  };

  users.users.root.openssh.authorizedKeys.keys = [ "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIOV4f3/OcNQIHqomvH0nGLDmXDlrO/u7JKE9Fgq2Vuqs me@netali.de" ];

  networking.dhcpcd.enable = false;
  networking.useDHCP = false;
}